;代碼清單11-1
;文件名：c11_mbr.asm
;文件說明：硬盤主引導扇區代碼 
;創建日期：2011-5-16 19:54

;設置堆棧段和棧指針 
mov ax,cs 
mov ss,ax
mov sp,0x7c00

;計算GDT所在的邏輯段地址 
mov ax,[cs:gdt_base+0x7c00] ;低16位 
mov dx,[cs:gdt_base+0x7c00+0x02] ;高16位 
mov bx,16 
div bx 
mov ds,ax ;令DS指向該段以進行操作
mov bx,dx ;段內起始偏移地址 

;創建0#描述符，它是空描述符，這是處理器的要求
mov dword [bx+0x00],0x00
mov dword [bx+0x04],0x00

;創建#1描述符，保護模式下的代碼段描述符
mov dword [bx+0x08],0x7c0001ff 
mov dword [bx+0x0c],0x00409800

;創建#2描述符，保護模式下的數據段描述符（文本模式下的顯示緩沖區） 
mov dword [bx+0x10],0x8000ffff 
mov dword [bx+0x14],0x0040920b

;創建#3描述符，保護模式下的堆棧段描述符
mov dword [bx+0x18],0x00007a00
mov dword [bx+0x1c],0x00409600

;初始化描述符表寄存器GDTR
mov word [cs: gdt_size+0x7c00],31 ;描述符表的界限（總字節數減一） 

lgdt [cs: gdt_size+0x7c00]

in al,0x92 ;南橋芯片內的端口 
or al,0000_0010B
out 0x92,al ;打開A20

cli ;保護模式下中斷機制尚未建立，應 
;禁止中斷 
mov eax,cr0
or eax,1
mov cr0,eax ;設置PE位

;以下進入保護模式... ...
jmp dword 0x0008:flush ;16位的描述符選擇子：32位偏移
;清流水線并串行化處理器 
[bits 32]

flush:
mov cx,00000000000_10_000B ;加載數據段選擇子(0x10)
mov ds,cx

;以下在屏幕上顯示"Protect mode OK." 
mov byte [0x00],'P' 
mov byte [0x02],'r'
mov byte [0x04],'o'
mov byte [0x06],'t'
mov byte [0x08],'e'
mov byte [0x0a],'c'
mov byte [0x0c],'t'
mov byte [0x0e],' '
mov byte [0x10],'m'
mov byte [0x12],'o'
mov byte [0x14],'d'
mov byte [0x16],'e'
mov byte [0x18],' '
mov byte [0x1a],'O'
mov byte [0x1c],'K'

;以下用簡單的示例來幫助闡述32位保護模式下的堆棧操作 
mov cx,00000000000_11_000B ;加載堆棧段選擇子
mov ss,cx
mov esp,0x7c00

mov ebp,esp ;保存堆棧指針 
push byte '.' ;壓入立即數（字節）

sub ebp,4
cmp ebp,esp ;判斷壓入立即數時，ESP是否減4 
jnz ghalt 
pop eax
mov [0x1e],al ;顯示句點 

ghalt: 
hlt ;已經禁止中斷，將不會被喚醒 

;-------------------------------------------------------------------------------

gdt_size dw 0
gdt_base dd 0x00007e00 ;GDT的物理地址 

times 510-($-$$) db 0
db 0x55,0xaa