[轉]SPICE仿真軟件基礎(整理)
現在常用的SPICE仿真軟件為方便用戶使用都提供了較好的用戶界面，在用仿真庫中的元器件連成原理圖后就可以進行仿真（當然要設置必要的仿真參數），但實際上只是用原理圖自動產生了SPICE的格式語句，還是要通過讀取語句來進行仿真，這是歷史的遺留問題。
在當時的技術條件下，不能用圖形方式輸入電路結構，只能通過文本文件來描述，也就是所謂網表。SPICE軟件的設計者規范了要進行仿真的電路對應的SPICE網表文件格式，還定義了許多仿真描述語句和分析控制語句等，使仿真軟件能通過讀取這些特殊信息來進行相關計算和運行，最后獲得要求的結果。
因為技術的進步，雖然現在已經不需要手工書寫并輸入網表了，但了解一些基本語句還是很有用的，不僅可以理解仿真時要設置的那些參數的含義，而且在出錯時還易于通過網表來排錯。
SPICE網表文件是文本文件，默認的輸入文件名為：*.cir
因為目前各個版本的SPICE軟件都已圖形化，并增加了很多功能，所以產生的語句順序和格式有了一些變化，但主要是以*開頭的注釋語句的不同變化，便于閱讀和模塊化，而基本的語句變化不大，包括以下幾種：
1) 標題語句：網表文件第一行為標題語句，由任意字符串和字母組成，軟件并不處理，而是直接在輸出文件中作為第一行打印出來
2) 注釋語句：由*開頭的字符串，為文件的說明部分，為方便閱讀而在自動產生的SPICE網表文件中大量存在
3) 電路描述語句：定義電路拓撲結構和元器件參數的語句，由元器件描述語句、模型描述語句、電源語句等組成
4) 電路特性分析和控制語句：以.開頭的語句，描述要分析的電路特性及控制命令
5) 結束語句：即.END ，標志電路描述語句的結束，在文件最后一行
（最后將會給出SPICE網表文件的例子）
一、電路描述語句：是SPICE網表文件中最多也最復雜的，有以下一些規定：
1) 名稱：為字符串，只有前8個字符有效，其中第一個字符必須為A--Z的字符，且有固定含義，對應不同類型的元件
2) 數字：有幾種形式，整數、浮點數、整數或浮點數加上整數指數、浮點數或整數后面加上比例因子
常用的比例因子：有T、G、MEG、K、M、U、N、P、F、MIL等，不分大小寫
3) 分隔符：有空格、逗號、等號、左括號、右括號等
4) 續行號：“+”，一行最多只能有80字符，如一行無法表達完全，可在第二行起始加+號，表示是前一行的繼續
5) 單位：使用國際標準單位制，語句中缺省
6) 規定支路電流的正方向和支路電壓的正方向一致
7) 節點編號：可以是任意的數字或字符串，節點0規定為地，不允許有懸浮的節點，即每個節點對0節點都必須有直流的通路。當實際電路不滿足這個要求時，可在懸浮節點與地之間接一個大電阻（如1G）.
8）不能分析的問題：電壓源回路、電感回路、電壓源和電感組成的回路、隔斷的電流源和（或）電容
以下分別介紹一些常見的電路描述語句：
1. 無源元件描述語句：由元件名、元件連接的節點號、元件的參數值組成
1.1 電阻描述語句：RXXXXXXX N+ N- <(MODEL)NAME> VALUE <TC=TC1 <TC2>>
其中：RXXXXXXX 元件名稱
N+ N- 電阻兩端的節點號，當電阻上加正電壓時，電流從N+流向N-
(MODEL)NAME 可選項，指出電阻將用上后面由.MODEL語句定義的模型
VALUE 電阻值，單位Ohm
TC=TC1 <TC2> 可選的溫度系數，TC1 TC2分別是一階、二階溫度系數
1.1.1 電阻的溫度公式：VALUE(T)=R*R0[1+TC1*(T-T0)+TC2*(T-T0)*(T-T0)]
其中：R0為電阻描述語句中的阻值，T0為常溫300K
1.1.2 電阻模型語句：.MODEL MNAME RES R=PVAL1 <TC1=PVAL2> <TC2=PVAL3> <TCE=PVAL4>
其中：RES為電阻模型關鍵字，R定義電阻倍乘系數，TCE定義指數溫度系數
1.1.3 例句：R4 0 3 RMOD 100
.MODEL RMOD RES(R=2 TC1=0.1 TC2=0.01)
1.2 電容電感描述語句：CXXXXXXX N+ N- <(MODEL)NAME> VALUE <IC=INCOND>
LXXXXXXX N+ N- <(MODEL)NAME> VALUE <IC=INCOND>
其中：VALUE為電容電感的值，不能為零
IC規定初始條件，僅在瞬態分析語句中設關鍵字UIC時賦值才有意義
1.2.1 電容電感模型語句：.MODEL MNAME CAP(C=PVAL1 VC1=PVAL2 VC2=PVAL3 TC1=PVAL4 TC2=PVAL5)
.MODEL MNAME IND(L=PVAL1 IL1=PVAL2 IL2=PVAL3 TC1=PVAL4 TC2=PVAL5)
其中：C、L定義電容電感的倍乘系數
VC1、VC2分別是電容的一階、二階電壓系數
IL1、IL2分別是電感的一階、二階電流系數
TC1、TC2分別是電容、電感的溫度系數
1.2.2 電容電感的求值公式：C(V)=C0*C(1+VC1*V+VC2*V*V)
L(I)=L0*L(1+IL1*I+IL2*I*I)
其中：C0、L0分別是元件描述語句中的值
1.2.3 電容電感的溫度公式與電阻的溫度公式類似
1.3 互感描述語句：KXXXXXXX LYYYYYYY LZZZZZZZ ... VALUE <(MODEL)NAME> <(SIZE)VALUE>
其中：KXXXXXXX、LYYYYYYY、LZZZZZZZ是兩個耦合電感的名稱，也可以將多個耦合電感按順序寫下去
VALUE為耦合系數的值，且0<VALUE<1，耦合規則通常在每個電感的第一個節點上加'.', 作為同名端
(MODEL)NAME為模型名，指出將用上后面由.MODEL語句定義的模型
(SIZE)VALUE用來定義磁芯的截面積的大小，缺省值為1
1.3.1 磁芯的模型語句：.MODEL MNAME CORE AREA=PVAL1 PATH=PVAL2 GAP=PVAL3 PACK=PVAL4 MS=...
1.4 無損傳輸線描述語句：TXXXXXXX N1 N2 N3 N4 Z0-VALUE <TD=VALUE> <F=FREQ <NL=NRMLEN>>
+<IC=V1,I1,V2,I2>
其中：無損傳輸線是二端口器件，N1、N2是端口1的正負節點，N3、N4是端口2的正負節點
Z0是特性阻抗
TD是傳輸延遲，頻率F及在頻率F時相對于傳輸波長的歸一化電學長度NL可用來確定延遲，兩種表示方式要選一種
IC確定每個端口的電壓和電流，只在瞬態分析中用到（加UIC時）
1.5 電壓控制開關描述語句：SXXXXXXX N+ N- NC+ NC- <(MODEL)NAME>
其中：N+ N-分別是開關的正負節點
NC+ NC-分別是控制端的正負節點
(MODEL)NAME為模型名，指出將用上后面由.MODEL語句定義的模型
1.5.1 電壓控制開關模型語句：.MODEL NAME VSWITCH RON=PVAL1 ROFF=PVAL2 VON=PVAL3 VOFF=PVAL4
其中：VSWITCH為壓控開關模型的關鍵字
RON定義開關的導通電阻，缺省為1歐姆
ROFF定義開關的關斷電阻，缺省為1兆歐姆
VON定義開關導通的閾值電壓
VOFF定義開關關斷的閾值電壓
1.6 電流控制開關的描述語句：WXXXXXXX N+ N- VNAME <(MODEL)NAME>
其中：N+ N-分別是開關的正負節點
VNAME是控制電流流過的電壓源的名稱
(MODEL)NAME為模型名，指出將用上后面由.MODEL語句定義的模型
1.6.1 電流控制開關模型語句：.MODEL ISMOD ISWITCH RON=PVAL1 ROFF=PVAL2 ION=PVAL3 IOFF=PVAL4
其中：ISWITCH為流控開關模型的關鍵字
ION為導通的閾值電流
IOFF為關斷的閾值電流
2. 有源元件描述語句：
2.1 二極管描述語句：DXXXXXXX N+ N- MNAME <AREA> <OFF> <IC=VD>
其中：N+ N-為二極管的正負節點
MNAME為二極管的模型名，為必選項
AREA為面積因子
OFF為直流分析時的初始條件
IC=VD為瞬態分析時的初始條件
2.1.1 二極管的模型語句：.MODEL MNAME D(PNAME1=PVAL1 PNAME2=PVAL2 ...)
其中：D為二極管模型的關鍵字，后面為二極管參數序列，一般二極管模型參數有15--25個
2.1.2 半導體二極管的參數表(帶*的受面積參數影響)：
2.2 雙極型晶體管描述語句：QXXXXXXX NC NB NE <NS> MNAME <AREA> <OFF> <IC=VBE,VCE>
其中：NC NB NE NS分別是雙極型晶體管的集電極、基極、發射極以及襯底所在節點，NS缺省表示襯底接地
MNAME為雙極型晶體管的模型名，為必選項
AREA為面積因子
OFF為直流分析時初始條件
IC=VBE,VCE為瞬態分析時初始條件
2.2.1 雙極型晶體管模型語句：.MODEL MNAME NPN(OR PNP) (PNAME=PVAL1 PNAME=PVAL2 ...)
雙極型晶體管模型有兩種類型，NPN PNP分別為其模型關鍵字，后面為參數序列，一般雙極型晶體管模型參數有40多個
2.2.2 雙極型晶體管模型的參數表(帶*的受面積參數影響)：
2.3 MOS場效應晶體管描述語句：MXXXXXXX ND NG NS NB MNAME <L=VAL> <W=VAL> <AD=VAL> <AS=VAL> <PD=VAL> <PS=VAL>
+<NRD=VAL> <NRS=VAL> <OFF> <IC=VDS,VGS,VBS>
其中：ND NG NS NB分別是MOS場效應晶體管的漏極、柵極、源極和襯底所在的節點
MNAME為MOS場效應晶體管的模型名，為必選項
L W分別是MOS場效應晶體管溝道的長、寬
AD AS為漏極和源極的擴散區的面積
PD PS為漏極和源極的周長
NRD NRS為漏極和源極擴散區等效電阻的方塊數
OFF為直流分析時初始條件
IC為瞬態分析時初始條件
2.3.1 MOS場效應晶體管模型語句：.MODEL MNAME NMOS(OR PMOS) (PNAME=PVAL1 PNAME=PVAL2 ...)
MOS場效應晶體管模型有兩種類型，NMOS PMOS分別為其模型關鍵字，后面為參數序列，一般模型參數有40--60個，大多為工藝參數
MOS場效應晶體管模型有四個級別，用語句LEVEL來指定，缺省時LEVEL=1
LEVEL=1 Shichman-Hadges模型
LEVEL=2 基于幾何圖形的一種二維分析模型
LEVEL=3 半經驗短溝道模型
LEVEL=4 亞微米BSIM模型
2.3.2 因MOS場效應晶體管模型的參數較多（40--60個）而且較復雜，很多與制造工藝有關，涉及太多微電子的知識，就不再列出了
系統級使用時一般使用相關制造廠商或第三方提供的模型參數
2.4 結型場效應晶體管描述語句：JXXXXXXX ND NG NS MNAME <AREA> <OFF> <IC=VDS,VGS>
其中：ND NG NS分別是結型場效應晶體管的漏極、柵極、源極所在的節點
MNAME為結型場效應晶體管的模型名，為必選項
AREA為面積因子
OFF為直流分析時初始條件
IC=VDS,VGS為瞬態分析時初始條件
2.4.1 結型場效應晶體管模型語句：.MODEL MNAME NJF(OR PJF) (PNAME=PVAL1 PNAME=PVAL2 ...)
結型場效應晶體管模型有兩種類型，NJF PJF分別為其模型關鍵字，后面為參數序列，一般模型參數有20多個，
結型場效應晶體管模型的參數也不再列出了，一般使用相關制造廠商或第三方提供的模型參數
2.5 GaAs場效應晶體管描述語句：BXXXXXXX ND NG NS MNAME <AREA> <OFF> <IC=VDS,VGS,VBS>
其中：ND NG NS分別是GaAs場效應晶體管漏極、柵極、源極所在的節點
MNAME為結型場效應晶體管的模型名，為必選項
AREA為面積因子
OFF為直流分析時初始條件
IC=VDS,VGS,VBS為瞬態分析時初始條件
2.5.1 GaAs場效應晶體管模型語句：.MODEL MNAME GASFET (PNAME=PVAL1 PNAME=PVAL2 ...)
GASFET為GaAs場效應晶體管模型的關鍵字，后面為參數序列，一般模型參數約30個
GaAs場效應晶體管模型有三個級別，用語句LEVEL來指定，缺省時LEVEL=1
LEVEL=1 Curtice模型
LEVEL=2 Statz或Raytheon模型
LEVEL=3 Triquint模型
GaAs場效應晶體管模型的參數也不再列出了，一般使用相關制造廠商或第三方提供的模型參數
2.6 數字電路器件描述語句：
UXXXXXXX <NAME> <PRIMITIVE TYPE> [(<PARAMETER VALUE>*)]
+<DIGITAL POWER NODE> <DIGITAL GROUND NODE> <NODE>*<TIMING MODELNAME>
+<I/OMODEL NAME> [MNTYMXDLY=<DELAY SELECT VALUE>]
+[I/O-LEVEL=<INTERFACE SUBKET SELECT VALUE>]
UXXXXXXX <STIM (WIDTH)VALUE,(FORMAT)VALUE> <NODE>*<(I/O)MODEL NAME>
+<TIMESTEP=(STEPSIZE)VALUE> <WAVEFORM DESCRIPTION>
前一種表示數字電路，名稱后是類型、參數值、節點、定時模型名、輸入輸出模型名
后一種表示激勵波形發生器，將規定的激勵加到指定的節點上
2.6.1 子電路描述語句：以.SUBCKT作為開始，以.END作為結束的一組語句，作為以X開始的元件
2.6.1.1 子電路定義開始語句：.SUBCKT <SUBNAME> N1 <N2 N3 ...>
其中：SUBNAME是子電路名稱
N1 N2 N3等是子電路外部節點號
2.6.1.2 子電路結束語句：.ENDS <SUBNAME>
表示結束SUBNAME子電路或結束所有子電路定義
2.7 元器件庫調用語句：.LIB <filename>
其中：filename為庫文件名，必須帶擴展名.lib，缺省名為nom.lib，列出所有庫文件
3. 電源描述語句：
3.1 獨立電源描述語句：
獨立電壓源描述語句：VXXXXXXX N+ N- <(DC)DC/TRAN VALUE> <AC (ACMAG (ACPHASE))>
獨立電流源描述語句：IXXXXXXX N+ N- <(DC)DC/TRAN VALUE> <AC (ACMAG (ACPHASE))>
參數含義：N+ N-為電源的正負節點，電流源的電流正方向為使電流從N+節點流出并流入N-節點
DC/TRAN VALUE指電源的直流或隨時間變化的瞬時值，缺省為0
獨立電源按直流、交流、瞬態源等可細分為如下幾種：
3.1.1 直流電源：
直流電壓源：VXXXXXXX N+ N- [DC] VALUE
直流電流源：IXXXXXXX N+ N- [DC] VALUE
3.1.2 交流電源：
交流電壓源：VXXXXXXX N+ N- AC <ACMEG <ACPHASE>>
交流電流源：IXXXXXXX N+ N- AC <ACMEG <ACPHASE>>
其中：ACMEG為正弦波幅值，缺省值為1
ACPHASE為正弦波的初始相位，缺省為0
3.1.3 瞬態電源：
脈沖電壓源：VXXXXXXX N+ N- PULSE (V1 V2 TR TF PW PER)
脈沖電流源：IXXXXXXX N+ N- PULSE (I1 I2 TR TF PW PER)
其中：V1 I1為起始值
V2 I2為脈動值
TD為延遲時間，缺省值為0
TR為上升時間，缺省值為TSTEP
TF為下降時間，缺省值為TSTEP
PW為脈沖寬度，缺省值為TSTOP
PER為周期，缺省值為TSTOP
(TSTEP TSTOP為瞬態分析時的步長和中止時間)
3.1.4 瞬態正弦電源：
瞬態正弦電壓源：VXXXXXXX N+ N- SIN (V0 VA F TD THETA)
瞬態正弦電流源：IXXXXXXX N+ N- SIN (I0 IA F TD THETA)
其中：V0 I0為偏置值
VA IA為振幅
F為頻率，缺省值為1/TSTOP
TD為延遲時間，缺省為0
THETA為阻尼時間，缺省為0
正弦曲線表達式：V(T)=V0+VA*SIN(2*PI*(F*(T-TD)+PHASE/360))*EXP(-(T-TD)*THETA)
I(T)=I0+IA*SIN(2*PI*(F*(T-TD)+PHASE/360))*EXP(-(T-TD)*THETA)
3.1.5 瞬態指數電源：
瞬態指數電壓源：VXXXXXXX N+ N- EXP(V1 V2 TD1 TAU1 TD2 TAU2)
瞬態指數電流源：IXXXXXXX N+ N- EXP(I1 I2 TD1 TAU1 TD2 TAU2)
其中：V1 I1為初始值
V2 I2為終止值
TD1為上升延遲時間，缺省為0
TAU1為上升時間常數，缺省為TSTEP
TD2為下降延遲時間，缺省為TD1+TSTEP
TAU2為下降時間常數，缺省為TSTEP
3.1.6 分段線性電源：
分段線性電壓源：VXXXXXXX N+ N- PWL (T1 V1 <T2 V2 T3 V3 T4 V4 ...>)
分段線性電流源：IXXXXXXX N+ N- PWL (T1 I1 <T2 I2 T3 I3 T4 I4 ...>)
3.1.7 瞬態單調調頻電源：
瞬態單調調頻電壓源：VXXXXXXX N+ N- SEFM (V0 VA FC MDI FS)
瞬態單調調頻電流源：IXXXXXXX N+ N- SEFM (I0 IA FC MDI FS)
其中：V0 I0為偏置
VA IA為幅度
FC為載波頻率，缺省值為1/TSTOP
MDI為調制系數
FS為信號頻率，缺省值為1/TSTOP
調頻曲線表達式：V(T)=V0+VA*SIN[(2*PI*FC*T)+MDI*SIN(2*PI*FS*T)]
3.2 線性受控源描述語句：
3.2.1 壓控電壓源：EXXXXXXX N+ N- NC+ NC- VALUE
其中：NC+ NC-為控制電壓支路的正負節點
3.2.2 壓控電流源：GXXXXXXX N+ N- NC+ NC- VALUE
3.2.3 流控電流源：HXXXXXXX N+ N- VNAME VALUE
其中：VNAME為控制電流流過的電壓源的名稱
3.2.4 流控電流源：FXXXXXXX N+ N- VNAME VALUE
二、分析語句：
1. 直流分析：
1.1 直流工作點分析：.OP
1.2 直流掃描分析：.DC <TYPE> VAR START STOP INC <VAR2 START2 STOP2>
其中：TYPE為掃描類型，線性為LIN、數量級為DEC、倍頻程為OCT、列表為LIST
VAR為掃描變量
START STOP為掃描變化范圍
INC是掃描步長或者點數，必須為正數
VAR2是第二個掃描變量（外循環），可選項
1.3 直流小信號傳輸函數分析：.TF OUTVAR INSRC
其中：OUTVAR為輸出變量
INSRC為小信號輸入源名稱
1.4 直流小信號靈敏度分析：.SENS
1.5 節點電壓設置：.NODESET
2. 交流小信號分析：.AC TYPE Nx FSTART FSTOP
2.1 主要的3種形式：線性 .AC LIN NP FSTART FSTOP
數量級 .AC DEC ND FSTART FSTOP
倍頻程 .AC OCT NO FSTART FSTOP
其中：NP為步長
ND為變化點數
NO為變化點數
2.2 噪聲分析：.NOISE OUTV INSRC NUMS
其中：OUTV為某節點上總的噪聲輸出電壓
INSRC為作噪聲輸入基準的獨立電壓源或獨立電流源名
NUMS為頻率間隔點數，在每個頻率處打印出電路中每個噪聲源的貢獻
3. 瞬態分析：
3.1 時域波形分析：.TRAN TSTART TSTOP DISPSTART STEPMAX
其中：TSTART為起點時間
TSTOP為終點時間
DISPSTART為顯示起點
STEPMAX為瞬態分析最大步長，可缺省而由系統選
3.2 傅立葉分析：.FOUR FREQ OV1 <OV2 OV3 ...>
其中：FREQ為基頻
OV1 OV2 OV3為要求的輸出變量
3.3 瞬態初始條件設置：.IC
4. 綜合分析：
4.1 最壞情況分析：.WCASE (ANALYSIS) (OUTVAR) <FUNCTION> <OPTION>
其中：ANALYSIS為DC/AC/TRAN中的一種
OUTVAR為輸出變量，電壓、電流等
FUNCTION為求值函數，有多種選擇
OPTION為輸出形式，LIST列每次運行模型參考值，OUTPUT輸出文件或圖形
4.2 蒙特卡羅分析：.MC (RUNSVAL) (ANALYSIS) <OUTPUTVAR> <FUNCTION> <OPTION>
其中：RUNSVAL為運行次數
OUTPUTVAR為輸出變量，電壓、電流等
4.3 參數掃描分析：.STEP
有3種類型：線性掃描 .STEP (LIN) VAR START STOP INC
數量級倍頻程掃描 .STEP <DEC> <OCT> VAR START STOP ND
列表掃描 .STEP VAR LIST VAL1 <VAL2 ...>
其中：INC為步長
ND為變化點數
4.4 溫度分析：.TEMP
三、控制語句：
1. 常用的控制語句如下：
1) 別名設置語句：.ALIASES和.ENDALIAS，中間為設置內容
2) 文本輸出文件中打印：.PRINT
3) 文本輸出文件中繪圖：.PLOT
4) 繪圖軟件包調用：.PROBE
5) 參數及表達式設置：.PARAM (NAME1=VALUE1) <NAME2=VALUE2> ...
其中的VALUE也可用表達式EXPR
6) 選擇項設置：.OPTION
7) 函數定義：.FUNC
2. PSPICE中的PROBE控制語句：當輸入文件中加入了.PROBE控制語句后，掃描計算結果存入*.dat文件中，可直觀觀察掃描結果
PROBE自動將橫坐標設為掃描變量，縱坐標需手動添加
PROBE提供Cursor工具，方便使用鼠標的左右鍵控制兩個光標，沿選定曲線進行測量，還有小窗口顯示光標對應的值還有兩光標間的差值
四、PSPICE中的變量掃描：對一些仿真參數，PSPICE可設置為變量，通過設置其變化范圍，仿真出不同的結果，以便進行對照以選擇最佳值
如：可把雙極型晶體管的偏置電阻設為變量，仿真出不同偏置電阻值時的放大系數及集電極電流等參數，最終可選擇最佳的偏置電阻值
可進行變量掃描的參數如下：
1) 獨立源類：任何獨立電壓源和獨立電流源都可以作為掃描變量
2) 模型參數類：任何一個.MODEL中描述的模型參數都可作為掃描變量，如溫度系數、場效應管的溝道長度和寬度等
3) 溫度變量：以TEMP作為掃描變量，可以觀察在不同溫度下的電路特性
4) 總體參數：對元器件值掃描，必須通過模型的設置來實現
熟練使用參數的變量掃描，可大大提高仿真效率
五、SPICE軟件的適用范圍及缺點：
1) SPICE是進行元器件級的仿真，對含元器件少的功能較單一的電路進行仿真較合適和準確，比如放大器、調制器等，但對結構復雜且器件較多的電路進行分析則比較費時，結果也可能偏離較大。
2) Spice采用變步長算法，對于周期性開關狀態變化的電力電子電路而言，將造成把大量的時間耗費在尋求合適的步長上面，從而導致計算時間的延長。
3) SPICE的器件模型都是針對小功率電子器件的，而對于電力電子電路中所用的大功率器件存在的高電壓、大注入現象不盡適用，有時甚至可能導致錯誤的結果。
4) SPICE的另一問題是仿真的收斂性問題，在對復雜電路進行仿真時，有時數據的準確性較低，甚至常出現不能收斂而導致仿真失敗。SPICE軟件更適合模擬電路仿真，可以做一些簡單的數字電路仿真，但用于數模混合電路時很容易出問題。
5) SPICE模型的分析精度主要取決于模型參數的來源(即數據的精確性)，以及模型方程式的適用范圍，而模型方程式與各種不同的數字仿真器相結合時也可能會影響分析的精度。
6) SPICE對元器件模型的依賴性很大，但這些參數通常都屬于設計者和制造商的知識產權和機密，常因缺乏模型導致仿真無法實現。目前美國、歐洲的半導體廠商的分立元件的SPICE模型較多，特別是著名廠商網站上都可下載，但日本生產的元件就很少有模型，而IC的模型更是少得多，通常還要購買。
7) SPICE最早主要是為集成電路設計開發的，半導體模型參數設計太多工藝參數和材料特性，而不是用戶手冊上的使用參數，使用非常不便，在遇到模型庫中未有的元件時，就難以仿真。雖然一些公司的SPICE軟件也有新建元器件模型的界面，如PSPICE，但因參數涉及很多微電子專業的術語，使用者不容易理解和轉換。
8) 因各方面原因，仿真結果與實際調試出的電路的測試結果都有一些誤差，而且常常在50%以上。
9) SPICE在應用于一些脈沖電路時，如方波發生器、多諧振蕩器、單穩觸發器、遲滯比較器等，也常常無法得到正確結果。
10) 許多諧振器和振蕩器電路都難以仿真。
11) RF電路仿真能力較差，阻抗匹配和阻抗園圖等都難以使用，各種端口參數也難以實現。
12) 在磁性元件的模型方面Spice也有待加強。
六、SPICE網表文件的實例：
1. 是軟件AIM-Spice附帶的實例，而直觀的原理圖卻沒有提供，可自己試著畫出來
（AIM-Spice是一個文本輸入的Spice軟件，功能單一且原始，但可免費下載，便于學習Spice。）
difpair ckt - simple differential pair
vin 1 0 sin(0 0.1 5meg) ac 1
vcc 8 0 12
vee 9 0 -12
q1 4 2 6 qnl
q2 5 3 6 qnl
rs1 1 2 1k
rs2 3 0 1k
rc1 4 8 10k
rc2 5 8 10k
q3 6 7 9 qnl
q4 7 7 9 qnl
rbias 7 8 20k
.model qnl npn(bf=80 rb=100 ccs=2pf tf=0.3ns tr=6ns cje=3pf cjc=2pf
+ va=50)
2. 用ORCAD10中附帶的PSPICE模塊自動產生的網表文件的實例（刪去了空行）：
**** 11/15/08 16:12:15 ******* PSpice 10.0.0 (Jan 2003) ******* ID# 1111111111
** Profile: "SCHEMATIC1-bias" [ D:\My Documents\orcad\transistor-pspicefiles\schematic1\bias.sim ]
**** CIRCUIT DESCRIPTION
******************************************************************************
** Creating circuit file "bias.cir"
** WARNING: THIS AUTOMATICALLY GENERATED FILE MAY BE OVERWRITTEN BY SUBSEQUENT SIMULATIONS
*Libraries:
* Profile Libraries :
* Local Libraries :
* From [PSPICE NETLIST] section of e:\OrCAD\OrCAD_10.0\tools\PSpice\PSpice.ini file:
.lib "nom.lib"
*Analysis directives:
.TRAN 0 20ms 10ms
.PROBE V(alias(*)) I(alias(*)) W(alias(*)) D(alias(*)) NOISE(alias(*))
.INC "..\SCHEMATIC1.net"
**** INCLUDING SCHEMATIC1.net ****
* source TRANSISTOR
Q_Q1 N00286 N00312 N00298 Q2N3904
R_R1 N00312 N00256 470k
R_R2 N00286 N00256 2.2k
R_R3 0 N00298 47
R_R5 0 N00374 10k
C_C1 N00423 N00312 100n
C_C2 N00286 N00374 100n
V_V1 N00256 0 6Vdc
V_V2 N00423 0 DC 0 AC 1
+SIN 0 1m 1k 0 0 0
**** RESUMING bias.cir ****
.END
其電路原理圖及交流小信號分析和瞬態分析波形如下：
浙公網安備 33010602011771號